build.gradle

buildscript {
	repositories {
		gradlePluginPortal()
		mavenCentral()
		mavenLocal()
	}
	dependencies {
		classpath "se.bjurr.gradle.java-convention:se.bjurr.gradle.java-convention.gradle.plugin:0.+"
		classpath "org.wiremock.tools.gradle:gradle-wiremock-extension-plugins:0.4.0"
	}
}

apply plugin: "project-report"
apply plugin: "se.bjurr.gradle.java-convention"

// Or else it will be 11 in wiremock-extension-convention
sourceCompatibility = 17
targetCompatibility = 17
apply plugin: "org.wiremock.tools.gradle.wiremock-extension-convention"


group 'org.wiremock.integrations'

// Because older version is set in wiremock-extension-convention
def wiremockVersion = "3.10.0"

configurations {
	all*.exclude group: 'org.eclipse.jetty', module: 'jetty-servlet'
	all*.exclude group: 'org.eclipse.jetty', module: 'jetty-servlets'
	all*.exclude group: 'org.eclipse.jetty', module: 'jetty-webapp'
	all*.exclude group: 'org.eclipse.jetty.http2', module: 'http2-server'
}

dependencies {
	implementation platform("org.eclipse.jetty:jetty-bom:12.0.15")
	api "org.wiremock:wiremock-jetty12:${wiremockVersion}"

	api "org.springframework.boot:spring-boot-test:3.3.4"
	api "org.springframework:spring-test:6.1.13"
	api "org.slf4j:slf4j-api:2.0.16"
	api 'org.junit.jupiter:junit-jupiter-api:5.11.2'

	testImplementation "org.wiremock:wiremock-jetty12:${wiremockVersion}"
	testImplementation "org.springframework.boot:spring-boot-starter-test:3.3.4"
	testImplementation 'org.assertj:assertj-core:3.26.3'
	testImplementation platform('org.junit:junit-bom:5.11.2')
	testImplementation 'org.junit.jupiter:junit-jupiter'
	testImplementation 'org.junit.platform:junit-platform-launcher'
	testImplementation 'io.rest-assured:rest-assured:5.5.0'

	constraints {
		implementation('org.apache.commons:commons-compress:1.26.0') {
			because 'version 1.24.0 has a vulnerability'
		}
	}
}

// Not using shadowJar, but currently not possible to disable in wiremock-extension-convention
shadowJar {
	mergeServiceFiles()

	exclude '**/*'
}